Initial project import

tools/v/examples/websocket/client-server/client.v

@@ -0,0 +1,63 @@
+// vtest build: present_openssl?
+module main
+
+import os
+import net.websocket
+import term
+
+// This client should be compiled an run in different consoles
+// it connects to the server who will broadcast your messages
+// to all other connected clients
+fn main() {
+	mut ws := start_client()!
+	defer {
+		unsafe {
+			ws.free()
+		}
+	}
+	println(term.green('client ${ws.id} ready'))
+	println('Write message and enter to send...')
+	for {
+		line := os.get_line()
+		if line == '' {
+			break
+		}
+		ws.write_string(line)!
+	}
+	ws.close(1000, 'normal') or {
+		eprintln(term.red('ws.close err: ${err}'))
+		exit(1)
+	}
+}
+
+fn start_client() !&websocket.Client {
+	mut ws := websocket.new_client('ws://localhost:30000')!
+	// mut ws := websocket.new_client('wss://echo.websocket.org:443')?
+	// use on_open_ref if you want to send any reference object
+	ws.on_open(fn (mut ws websocket.Client) ! {
+		println(term.green('ws.on_open websocket connected to the server and ready to send messages...'))
+	})
+	// use on_error_ref if you want to send any reference object
+	ws.on_error(fn (mut ws websocket.Client, err string) ! {
+		println(term.red('ws.on_error error: ${err}'))
+	})
+	// use on_close_ref if you want to send any reference object
+	ws.on_close(fn (mut ws websocket.Client, code int, reason string) ! {
+		println(term.green('ws.on_close the connection to the server successfully closed'))
+	})
+	// on new messages from other clients, display them in blue text
+	ws.on_message(fn (mut ws websocket.Client, msg &websocket.Message) ! {
+		if msg.payload.len > 0 {
+			message := msg.payload.bytestr()
+			println(term.blue('ws.on_message `${message}`'))
+		}
+	})
+
+	ws.connect() or {
+		eprintln(term.red('ws.connect error: ${err}'))
+		return err
+	}
+
+	spawn ws.listen() // or { println(term.red('error on listen ${err}')) }
+	return ws
+}

tools/v/examples/websocket/client-server/server.v

@@ -0,0 +1,60 @@
+// vtest build: present_openssl?
+module main
+
+import net.websocket
+import term
+
+fn slog(message string) {
+	eprintln(term.colorize(term.bright_yellow, message))
+}
+
+// this server accepts client connections and broadcast all messages to other connected clients
+fn main() {
+	eprintln('press ctrl-c to quit...')
+	start_server()!
+}
+
+fn start_server() ! {
+	slog('start_server')
+	mut s := websocket.new_server(.ip6, 30000, '')
+	defer {
+		unsafe {
+			s.free()
+		}
+	}
+	// Make that in execution test time give time to execute at least one time
+	s.set_ping_interval(100)
+	s.on_connect(fn (mut s websocket.ServerClient) !bool {
+		slog('s.on_connect')
+		// Here you can look att the client info and accept or not accept
+		// just returning a true/false
+		if s.resource_name != '/' {
+			return false
+		}
+		return true
+	})!
+
+	// on_message_ref, broadcast all incoming messages to all clients except the one sent it
+	s.on_message_ref(fn (mut ws websocket.Client, msg &websocket.Message, mut m websocket.Server) ! {
+		slog('s.on_message_ref')
+		// for _, cli in m.clients {
+		for i, _ in rlock m.server_state {
+			m.server_state.clients
+		} {
+			mut c := rlock m.server_state {
+				m.server_state.clients[i] or { continue }
+			}
+			if c.client.get_state() == .open && c.client.id != ws.id {
+				c.client.write(msg.payload, websocket.OPCode.text_frame) or { panic(err) }
+			}
+		}
+	}, s)
+
+	s.on_close(fn (mut ws websocket.Client, code int, reason string) ! {
+		slog('s.on_close')
+		println(term.green('client (${ws.id}) closed connection'))
+	})
+
+	s.listen() or { println(term.red('error on server listen: ${err}')) }
+	slog('s.listen done')
+}