Initial project import

tools/v/examples/dynamic_library_loading/modules/library/library.v

@@ -0,0 +1,19 @@
+module library
+
+// add_1 is exported with the C name `add_1`.
+// It can be called by external programs, when the module is compiled
+// as a shared library.
+// It is exported, because the function is declared as public with `pub`.
+// The exported C name is `add_1`, because of the export: tag.
+// (Normally, the exported name is a V mangled version based on the module
+// name followed by __, followed by the fn name, i.e. it would have been
+// `library__add_1`, if not for the export: tag).
+@[export: 'add_1']
+pub fn add_1(x int, y int) int {
+	return my_private_function(x + y)
+}
+
+// this function is not exported and will not be visible to external programs.
+fn my_private_function(x int) int {
+	return 1 + x
+}

tools/v/examples/dynamic_library_loading/use_dl_module.v

@@ -0,0 +1,19 @@
+module main
+
+// Note: This program, requires that the shared library was already compiled.
+// To do so, run `v -d no_backtrace -o library -shared modules/library/library.v`
+// before running this program.
+import os
+import dl
+
+type FNAdder = fn (int, int) int
+
+fn main() {
+	library_file_path := os.join_path(os.dir(@FILE), dl.get_libname('library'))
+	handle := dl.open_opt(library_file_path, dl.rtld_lazy)!
+	eprintln('handle: ${ptr_str(handle)}')
+	f := FNAdder(dl.sym_opt(handle, 'add_1')!)
+	eprintln('f: ${ptr_str(f)}')
+	res := f(1, 2)
+	eprintln('res: ${res}')
+}

tools/v/examples/dynamic_library_loading/use_library_test.v

@@ -0,0 +1,65 @@
+module main
+
+// vtest retry: 3
+import os
+import dl
+
+const vexe = os.real_path(os.getenv('VEXE'))
+const cfolder = os.dir(@FILE)
+const so_ext = dl.dl_ext
+const library_file_name = os.join_path(cfolder, dl.get_libname('library'))
+
+fn test_vexe() {
+	// dump(vexe)
+	assert vexe != ''
+	// dump(os.executable())
+	// dump(@FILE)
+	// dump(cfolder)
+	// dump(so_ext)
+	// dump(library_file_name)
+}
+
+fn test_can_compile_library() {
+	os.chdir(cfolder) or {}
+	os.rm(library_file_name) or {}
+	v_compile('-d no_backtrace -o library -shared modules/library/library.v')
+	assert os.is_file(library_file_name)
+}
+
+fn test_can_compile_main_program() {
+	os.chdir(cfolder) or {}
+	assert os.is_file(library_file_name)
+	result := v_compile('run use_dl_module.v')
+	// dump(result)
+	assert result.output.contains('res: 4')
+	os.rm(library_file_name) or {}
+}
+
+fn test_can_compile_and_use_library_with_skip_unused() {
+	os.chdir(cfolder) or {}
+	os.rm(library_file_name) or {}
+	v_compile('-skip-unused -d no_backtrace -o library -shared modules/library/library.v')
+	assert os.is_file(library_file_name)
+	result := v_compile('run use_dl_module.v')
+	assert result.output.contains('res: 4')
+	os.rm(library_file_name) or {}
+}
+
+fn test_can_compile_and_use_library_with_prod() {
+	os.chdir(cfolder) or {}
+	os.rm(library_file_name) or {}
+	v_compile('-prod -d no_backtrace -o library -shared modules/library/library.v')
+	assert os.is_file(library_file_name)
+	result := v_compile('run use_dl_module.v')
+	assert result.output.contains('res: 4')
+	os.rm(library_file_name) or {}
+}
+
+fn v_compile(vopts string) os.Result {
+	cmd := '${os.quoted_path(vexe)} -showcc ${vopts}'
+	// dump(cmd)
+	res := os.execute_or_exit(cmd)
+	// dump(res)
+	assert res.exit_code == 0
+	return res
+}